Add CMake build system

Summary: This is for use on Windows only, and does not support Linux or OSX in the slightest. There are probably still a few hacks laying around in it, but it works, and that's good enough for now.

Reviewed By: yfeldblum

Differential Revision: D4873498

fbshipit-source-id: 5952a927037dc1d56c51e71d51ba506d2cd17357

CMake/FindDoubleConversion.cmake

+# Finds libdouble-conversion.
+#
+# This module defines:
+# DOUBLE_CONVERSION_INCLUDE_DIR
+# DOUBLE_CONVERSION_LIBRARY
+#
+
+find_path(DOUBLE_CONVERSION_INCLUDE_DIR double-conversion/double-conversion.h)
+find_library(DOUBLE_CONVERSION_LIBRARY NAMES double-conversion)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(
+    DOUBLE_CONVERSION DEFAULT_MSG
+    DOUBLE_CONVERSION_LIBRARY DOUBLE_CONVERSION_INCLUDE_DIR)
+
+if (NOT DOUBLE_CONVERSION_FOUND)
+  message(STATUS "Using third-party bundled double-conversion")
+else()
+  message(STATUS "Found double-conversion: ${DOUBLE_CONVERSION_LIBRARY}")
+endif (NOT DOUBLE_CONVERSION_FOUND)
+
+mark_as_advanced(DOUBLE_CONVERSION_INCLUDE_DIR DOUBLE_CONVERSION_LIBRARY)

CMake/FindGFlags.cmake

+#
+# Find libgflags
+#
+#  LIBGFLAGS_INCLUDE_DIR - where to find gflags/gflags.h, etc.
+#  LIBGFLAGS_LIBRARY     - List of libraries when using libgflags.
+#  LIBGFLAGS_FOUND       - True if libgflags found.
+
+
+IF (LIBGFLAGS_INCLUDE_DIR)
+  # Already in cache, be silent
+  SET(LIBGFLAGS_FIND_QUIETLY TRUE)
+ENDIF ()
+
+FIND_PATH(LIBGFLAGS_INCLUDE_DIR gflags/gflags.h)
+
+FIND_LIBRARY(LIBGFLAGS_LIBRARY gflags)
+
+# handle the QUIETLY and REQUIRED arguments and set LIBGFLAGS_FOUND to TRUE if
+# all listed variables are TRUE
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBGFLAGS DEFAULT_MSG LIBGFLAGS_LIBRARY LIBFLAGS_INCLUDE_DIR)
+
+MARK_AS_ADVANCED(LIBGFLAGS_LIBRARY LIBGFLAGS_INCLUDE_DIR)

CMake/FindGMock.cmake

+#
+# Find libgmock
+#
+#  LIBGMOCK_INCLUDE_DIR - where to find gmock/gmock.h, etc.
+#  LIBGMOCK_LIBRARY     - List of libraries when using libgmock.
+#  LIBGMOCK_FOUND       - True if libgmock found.
+
+
+IF (LIBGMOCK_INCLUDE_DIR)
+  # Already in cache, be silent
+  SET(LIBGMOCK_FIND_QUIETLY TRUE)
+ENDIF ()
+
+FIND_PATH(LIBGMOCK_INCLUDE_DIR gmock/gmock.h)
+
+FIND_LIBRARY(LIBGMOCK_LIBRARY gmock_main)
+
+# handle the QUIETLY and REQUIRED arguments and set LIBGMOCK_FOUND to TRUE if
+# all listed variables are TRUE
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBGMOCK DEFAULT_MSG LIBGMOCK_LIBRARY LIBGMOCK_INCLUDE_DIR)
+
+MARK_AS_ADVANCED(LIBGMOCK_LIBRARY LIBGMOCK_INCLUDE_DIR)

CMake/FindGlog.cmake

+#
+# Find libglog
+#
+#  LIBGLOG_INCLUDE_DIR - where to find glog/logging.h, etc.
+#  LIBGLOG_LIBRARY     - List of libraries when using libglog.
+#  LIBGLOG_FOUND       - True if libglog found.
+
+
+IF (LIBGLOG_INCLUDE_DIR)
+  # Already in cache, be silent
+  SET(LIBGLOG_FIND_QUIETLY TRUE)
+ENDIF ()
+
+FIND_PATH(LIBGLOG_INCLUDE_DIR glog/logging.h)
+
+FIND_LIBRARY(LIBGLOG_LIBRARY glog)
+
+# handle the QUIETLY and REQUIRED arguments and set LIBGLOG_FOUND to TRUE if
+# all listed variables are TRUE
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBGLOG DEFAULT_MSG LIBGLOG_LIBRARY LIBGLOG_INCLUDE_DIR)
+
+MARK_AS_ADVANCED(LIBGLOG_LIBRARY LIBGLOG_INCLUDE_DIR)

CMake/FindLibEvent.cmake

+# - Find LibEvent (a cross event library)
+# This module defines
+# LIBEVENT_INCLUDE_DIR, where to find LibEvent headers
+# LIBEVENT_LIB, LibEvent libraries
+# LibEvent_FOUND, If false, do not try to use libevent
+
+set(LibEvent_EXTRA_PREFIXES /usr/local /opt/local "$ENV{HOME}")
+foreach(prefix ${LibEvent_EXTRA_PREFIXES})
+  list(APPEND LibEvent_INCLUDE_PATHS "${prefix}/include")
+  list(APPEND LibEvent_LIB_PATHS "${prefix}/lib")
+endforeach()
+
+find_path(LIBEVENT_INCLUDE_DIR event.h PATHS ${LibEvent_INCLUDE_PATHS})
+find_library(LIBEVENT_LIB NAMES event PATHS ${LibEvent_LIB_PATHS})
+
+if (LIBEVENT_LIB AND LIBEVENT_INCLUDE_DIR)
+  set(LibEvent_FOUND TRUE)
+  set(LIBEVENT_LIB ${LIBEVENT_LIB})
+else ()
+  set(LibEvent_FOUND FALSE)
+endif ()
+
+if (LibEvent_FOUND)
+  if (NOT LibEvent_FIND_QUIETLY)
+    message(STATUS "Found libevent: ${LIBEVENT_LIB}")
+  endif ()
+else ()
+  if (LibEvent_FIND_REQUIRED)
+    message(FATAL_ERROR "Could NOT find libevent.")
+  endif ()
+  message(STATUS "libevent NOT found.")
+endif ()
+
+mark_as_advanced(
+    LIBEVENT_LIB
+    LIBEVENT_INCLUDE_DIR
+  )

CMake/FindPThread.cmake

+# - Try to find libpthread
+#
+# Once done this will define
+#
+#  LIBPTHREAD_FOUND - system has libpthread
+#  LIBPTHREAD_INCLUDE_DIRS - the libpthread include directory
+#  LIBPTHREAD_LIBRARIES - Link these to use libpthread
+#  LIBPTHREAD_DEFINITIONS - Compiler switches required for using libpthread
+#
+#  Redistribution and use is allowed according to the terms of the New
+#  BSD license.
+#  For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+
+
+if (LIBPTHREAD_LIBRARIES AND LIBPTHREAD_INCLUDE_DIRS)
+  set (LIBPTHREAD_FIND_QUIETLY TRUE)
+endif (LIBPTHREAD_LIBRARIES AND LIBPTHREAD_INCLUDE_DIRS)
+
+find_path (LIBPTHREAD_INCLUDE_DIRS NAMES pthread.h)
+find_library (LIBPTHREAD_LIBRARIES NAMES pthread)
+
+include (FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBPTHREAD DEFAULT_MSG
+  LIBPTHREAD_LIBRARIES LIBPTHREAD_INCLUDE_DIRS)
+
+mark_as_advanced(LIBPTHREAD_INCLUDE_DIRS LIBPTHREAD_LIBRARIES LIBPTHREAD_FOUND)

CMake/folly-config.h.cmake

+/*
+ * Copyright 2016 Facebook, Inc.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *   http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+#pragma once
+
+#define FOLLY_HAVE_LIBGFLAGS 1
+#define FOLLY_UNUSUAL_GFLAGS_NAMESPACE 1
+#define FOLLY_GFLAGS_NAMESPACE google
+
+#define FOLLY_HAVE_IFUNC 0
+#define FOLLY_HAVE_MALLOC_H 1
+#define FOLLY_HAVE_MEMRCHR 0
+#define FOLLY_HAVE_PREADV 0
+#define FOLLY_HAVE_PTHREAD_SPINLOCK_T 1
+#define FOLLY_HAVE_PWRITEV 0
+#define FOLLY_HAVE_SCHED_H 1
+#define FOLLY_HAVE_STD__IS_TRIVIALLY_COPYABLE 1
+#define FOLLY_HAVE_STD_THIS_THREAD_SLEEP_FOR 1
+#define FOLLY_HAVE_UNALIGNED_ACCESS 1
+#define FOLLY_HAVE_VLA 0
+#define FOLLY_HAVE_WEAK_SYMBOLS 0
+
+#define FOLLY_VERSION "${PACKAGE_VERSION}"
+
+//#define FOLLY_HAVE_LIBLZ4 1
+//#define FOLLY_HAVE_LIBLZMA 1
+//#define FOLLY_HAVE_LIBSNAPPY 1
+//#define FOLLY_HAVE_LIBZ 1
+//#define FOLLY_HAVE_LIBZSTD 1

CMake/folly-deps.cmake

+find_package(Boost 1.55.0 MODULE
+  COMPONENTS
+    context
+    chrono
+    date_time
+    filesystem
+    program_options
+    regex
+    system
+    thread
+  REQUIRED
+)
+find_package(DoubleConversion MODULE REQUIRED)
+find_package(GFlags MODULE REQUIRED)
+find_package(GLog MODULE REQUIRED)
+find_package(LibEvent MODULE REQUIRED)
+find_package(OpenSSL MODULE REQUIRED)
+find_package(PThread MODULE REQUIRED)