watchman:folly:thrift:wangle:fizz: move CMake library bits to a central location

Summary:
Use the watchman cmake files to seed the common cmake library and adjust
a number of our opensource projects to take their glog and gflags module
finding from that central location.

Note that there are a variety of ad-hoc re-implementations of shipit in various build scripts used in sandcastle jobs at the moment that result in adding multiple cmake module paths to correctly locate the shared cmake directory.  The long term solution is to get all those projects integrated in the new fbcode_builder stuff that I'm working on.

Reviewed By: simpkins, calebmarchent

Differential Revision: D14549654

fbshipit-source-id: e49a7f20a15af52b4b3ed3037b8973fc293656dc

CMake/FindGFlags.cmake

-#
-# Find libgflags
-#
-#  LIBGFLAGS_INCLUDE_DIR - where to find gflags/gflags.h, etc.
-#  LIBGFLAGS_LIBRARY     - List of libraries when using libgflags.
-#  LIBGFLAGS_FOUND       - True if libgflags found.
-
-
-IF (LIBGFLAGS_INCLUDE_DIR)
-  # Already in cache, be silent
-  SET(LIBGFLAGS_FIND_QUIETLY TRUE)
-ENDIF ()
-
-FIND_PATH(LIBGFLAGS_INCLUDE_DIR gflags/gflags.h)
-
-FIND_LIBRARY(LIBGFLAGS_LIBRARY_DEBUG NAMES gflagsd gflags_staticd)
-FIND_LIBRARY(LIBGFLAGS_LIBRARY_RELEASE NAMES gflags gflags_static)
-
-INCLUDE(SelectLibraryConfigurations)
-SELECT_LIBRARY_CONFIGURATIONS(LIBGFLAGS)
-
-# handle the QUIETLY and REQUIRED arguments and set LIBGFLAGS_FOUND to TRUE if
-# all listed variables are TRUE
-INCLUDE(FindPackageHandleStandardArgs)
-FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBGFLAGS DEFAULT_MSG LIBGFLAGS_LIBRARY LIBGFLAGS_INCLUDE_DIR)
-
-MARK_AS_ADVANCED(LIBGFLAGS_LIBRARY LIBGFLAGS_INCLUDE_DIR)

CMake/FindGLog.cmake

-#
-# Find libglog
-#
-#  LIBGLOG_INCLUDE_DIR - where to find glog/logging.h, etc.
-#  LIBGLOG_LIBRARY     - List of libraries when using libglog.
-#  LIBGLOG_FOUND       - True if libglog found.
-
-
-IF (LIBGLOG_INCLUDE_DIR)
-  # Already in cache, be silent
-  SET(LIBGLOG_FIND_QUIETLY TRUE)
-ENDIF ()
-
-FIND_PATH(LIBGLOG_INCLUDE_DIR glog/logging.h)
-
-FIND_LIBRARY(LIBGLOG_LIBRARY glog)
-
-# handle the QUIETLY and REQUIRED arguments and set LIBGLOG_FOUND to TRUE if
-# all listed variables are TRUE
-INCLUDE(FindPackageHandleStandardArgs)
-FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBGLOG DEFAULT_MSG LIBGLOG_LIBRARY LIBGLOG_INCLUDE_DIR)
-
-MARK_AS_ADVANCED(LIBGLOG_LIBRARY LIBGLOG_INCLUDE_DIR)

CMake/folly-deps.cmake

@@ -21,40 +21,17 @@ find_package(DoubleConversion MODULE REQUIRED)
 list(APPEND FOLLY_LINK_LIBRARIES ${DOUBLE_CONVERSION_LIBRARY})
 list(APPEND FOLLY_INCLUDE_DIRECTORIES ${DOUBLE_CONVERSION_INCLUDE_DIR})
 
-set(FOLLY_HAVE_LIBGFLAGS OFF)
-find_package(gflags CONFIG QUIET)
-if (gflags_FOUND)
-  message(STATUS "Found gflags from package config")
-  message(STATUS "gflags_CONFIG=${gflags_CONFIG}")
-  set(FOLLY_HAVE_LIBGFLAGS ON)
-  # ${GFLAGS_TARGET} contains the desired gflags target to depend on.
-  # The ${gflags_LIBRARIES} variable is an alias to it, and is more compatible
-  # with older versions of gflags.
-  message(STATUS "Using gflags libraries ${gflags_LIBRARIES}")
-  list(APPEND FOLLY_SHINY_DEPENDENCIES ${gflags_LIBRARIES})
-  list(APPEND CMAKE_REQUIRED_LIBRARIES ${GFLAGS_LIBRARIES})
-  list(APPEND CMAKE_REQUIRED_INCLUDES ${GFLAGS_INCLUDE_DIR})
-else()
-  find_package(GFlags MODULE)
-  set(FOLLY_HAVE_LIBGFLAGS ${LIBGFLAGS_FOUND})
-  list(APPEND FOLLY_LINK_LIBRARIES ${LIBGFLAGS_LIBRARY})
-  list(APPEND FOLLY_INCLUDE_DIRECTORIES ${LIBGFLAGS_INCLUDE_DIR})
-  list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBGFLAGS_LIBRARY})
-  list(APPEND CMAKE_REQUIRED_INCLUDES ${LIBGFLAGS_INCLUDE_DIR})
-endif()
-
-set(FOLLY_HAVE_LIBGLOG OFF)
-find_package(glog CONFIG QUIET)
-if (glog_FOUND)
-  message(STATUS "Found glog from package config")
-  set(FOLLY_HAVE_LIBGLOG ON)
-  list(APPEND FOLLY_SHINY_DEPENDENCIES glog::glog)
-else()
-  find_package(GLog MODULE)
-  set(FOLLY_HAVE_LIBGLOG ${LIBGLOG_FOUND})
-  list(APPEND FOLLY_LINK_LIBRARIES ${LIBGLOG_LIBRARY})
-  list(APPEND FOLLY_INCLUDE_DIRECTORIES ${LIBGLOG_INCLUDE_DIR})
-endif()
+find_package(Gflags MODULE)
+set(FOLLY_HAVE_LIBGFLAGS ${LIBGFLAGS_FOUND})
+list(APPEND FOLLY_LINK_LIBRARIES ${LIBGFLAGS_LIBRARY})
+list(APPEND FOLLY_INCLUDE_DIRECTORIES ${LIBGFLAGS_INCLUDE_DIR})
+list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBGFLAGS_LIBRARY})
+list(APPEND CMAKE_REQUIRED_INCLUDES ${LIBGFLAGS_INCLUDE_DIR})
+
+find_package(Glog MODULE)
+set(FOLLY_HAVE_LIBGLOG ${GLOG_FOUND})
+list(APPEND FOLLY_LINK_LIBRARIES ${GLOG_LIBRARY})
+list(APPEND FOLLY_INCLUDE_DIRECTORIES ${GLOG_INCLUDE_DIR})
 
 find_package(Libevent CONFIG QUIET)
 if(TARGET event)

CMakeLists.txt

@@ -14,7 +14,13 @@ if(POLICY CMP0075)
 endif()
 
 # includes
-set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
+set(CMAKE_MODULE_PATH
+  "${CMAKE_CURRENT_SOURCE_DIR}/CMake"
+  # for in-fbsource builds
+  "${CMAKE_CURRENT_SOURCE_DIR}/../opensource/fbcode_builder/CMake"
+  # For shipit-transformed builds
+  "${CMAKE_CURRENT_SOURCE_DIR}/build/fbcode_builder/CMake"
+  ${CMAKE_MODULE_PATH})
 
 # package information
 set(PACKAGE_NAME      "folly")

build/fbcode_builder/CMake/FindGflags.cmake

+# Find libgflags.
+# There's a lot of compatibility cruft going on in here, both
+# to deal with changes across the FB consumers of this and also
+# to deal with variances in behavior of cmake itself.
+#
+# Since this file is named FindGflags.cmake the cmake convention
+# is for the module to export both GFLAGS_FOUND and Gflags_FOUND.
+# The convention expected by consumers is that we export the
+# following variables, even though these do not match the cmake
+# conventions:
+#
+#  LIBGFLAGS_INCLUDE_DIR - where to find gflags/gflags.h, etc.
+#  LIBGFLAGS_LIBRARY     - List of libraries when using libgflags.
+#  LIBGFLAGS_FOUND       - True if libgflags found.
+#
+# We need to be able to locate gflags both from an installed
+# cmake config file and just from the raw headers and libs, so
+# test for the former and then the latter, and then stick
+# the results together and export them into the variables
+# listed above.
+#
+# For forwards compatibility, we export the following variables:
+#
+#  gflags_INCLUDE_DIR - where to find gflags/gflags.h, etc.
+#  gflags_TARGET / GFLAGS_TARGET / gflags_LIBRARIES
+#                     - List of libraries when using libgflags.
+#  gflags_FOUND       - True if libgflags found.
+#
+
+IF (LIBGFLAGS_INCLUDE_DIR)
+  # Already in cache, be silent
+  SET(Gflags_FIND_QUIETLY TRUE)
+ENDIF ()
+
+find_package(gflags CONFIG QUIET)
+if (gflags_FOUND)
+  if (NOT Gflags_FIND_QUIETLY)
+    message(STATUS "Found gflags from package config ${gflags_CONFIG}")
+  endif()
+  # Re-export the config-specified libs with our local names
+  set(LIBGFLAGS_LIBRARY ${gflags_LIBRARIES})
+  set(LIBGFLAGS_INCLUDE_DIR ${gflags_INCLUDE_DIR})
+  set(LIBGFLAGS_FOUND ${gflags_FOUND})
+  # cmake module compat
+  set(GFLAGS_FOUND ${gflags_FOUND})
+  set(Gflags_FOUND ${gflags_FOUND})
+else()
+  FIND_PATH(LIBGFLAGS_INCLUDE_DIR gflags/gflags.h)
+
+  FIND_LIBRARY(LIBGFLAGS_LIBRARY_DEBUG NAMES gflagsd gflags_staticd)
+  FIND_LIBRARY(LIBGFLAGS_LIBRARY_RELEASE NAMES gflags gflags_static)
+
+  INCLUDE(SelectLibraryConfigurations)
+  SELECT_LIBRARY_CONFIGURATIONS(LIBGFLAGS)
+
+  # handle the QUIETLY and REQUIRED arguments and set LIBGFLAGS_FOUND to TRUE if
+  # all listed variables are TRUE
+  INCLUDE(FindPackageHandleStandardArgs)
+  FIND_PACKAGE_HANDLE_STANDARD_ARGS(gflags DEFAULT_MSG LIBGFLAGS_LIBRARY LIBGFLAGS_INCLUDE_DIR)
+  # cmake module compat
+  set(Gflags_FOUND ${GFLAGS_FOUND})
+  # compat with some existing FindGflags consumers
+  set(LIBGFLAGS_FOUND ${GFLAGS_FOUND})
+
+  # Compat with the gflags CONFIG based detection
+  set(gflags_FOUND ${GFLAGS_FOUND})
+  set(gflags_INCLUDE_DIR ${LIBGFLAGS_INCLUDE_DIR})
+  set(gflags_LIBRARIES ${LIBGFLAGS_LIBRARY})
+  set(GFLAGS_TARGET ${LIBGFLAGS_LIBRARY})
+  set(gflags_TARGET ${LIBGFLAGS_LIBRARY})
+
+  MARK_AS_ADVANCED(LIBGFLAGS_LIBRARY LIBGFLAGS_INCLUDE_DIR)
+endif()
+
+# Compat with the gflags CONFIG based detection
+if (LIBGFLAGS_FOUND AND NOT TARGET gflags)
+  add_library(gflags UNKNOWN IMPORTED)
+  set_target_properties(gflags PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${LIBGFLAGS_INCLUDE_DIR}")
+  set_target_properties(gflags PROPERTIES IMPORTED_LINK_INTERFACE_LANGUAGES "C" IMPORTED_LOCATION "${LIBGFLAGS_LIBRARY}")
+endif()

build/fbcode_builder/CMake/FindGlog.cmake

+# - Try to find Glog
+# Once done, this will define
+#
+# GLOG_FOUND - system has Glog
+# GLOG_INCLUDE_DIRS - the Glog include directories
+# GLOG_LIBRARIES - link these to use Glog
+
+include(FindPackageHandleStandardArgs)
+
+find_library(GLOG_LIBRARY glog
+  PATHS ${GLOG_LIBRARYDIR})
+
+find_path(GLOG_INCLUDE_DIR glog/logging.h
+  PATHS ${GLOG_INCLUDEDIR})
+
+find_package_handle_standard_args(glog DEFAULT_MSG
+  GLOG_LIBRARY
+  GLOG_INCLUDE_DIR)
+
+mark_as_advanced(
+  GLOG_LIBRARY
+  GLOG_INCLUDE_DIR)
+
+set(GLOG_LIBRARIES ${GLOG_LIBRARY})
+set(GLOG_INCLUDE_DIRS ${GLOG_INCLUDE_DIR})
+
+if (NOT TARGET glog::glog)
+  add_library(glog::glog UNKNOWN IMPORTED)
+  set_target_properties(glog::glog PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${GLOG_INCLUDE_DIRS}")
+  set_target_properties(glog::glog PROPERTIES IMPORTED_LINK_INTERFACE_LANGUAGES "C" IMPORTED_LOCATION "${GLOG_LIBRARIES}")
+endif()

build/fbcode_builder/CMake/FindLibEvent.cmake

+# - Find LibEvent (a cross event library)
+# This module defines
+# LIBEVENT_INCLUDE_DIR, where to find LibEvent headers
+# LIBEVENT_LIB, LibEvent libraries
+# LibEvent_FOUND, If false, do not try to use libevent
+
+set(LibEvent_EXTRA_PREFIXES /usr/local /opt/local "$ENV{HOME}")
+foreach(prefix ${LibEvent_EXTRA_PREFIXES})
+  list(APPEND LibEvent_INCLUDE_PATHS "${prefix}/include")
+  list(APPEND LibEvent_LIB_PATHS "${prefix}/lib")
+endforeach()
+
+find_path(LIBEVENT_INCLUDE_DIR event.h PATHS ${LibEvent_INCLUDE_PATHS})
+find_library(LIBEVENT_LIB NAMES event PATHS ${LibEvent_LIB_PATHS})
+
+if (LIBEVENT_LIB AND LIBEVENT_INCLUDE_DIR)
+  set(LibEvent_FOUND TRUE)
+  set(LIBEVENT_LIB ${LIBEVENT_LIB})
+else ()
+  set(LibEvent_FOUND FALSE)
+endif ()
+
+if (LibEvent_FOUND)
+  if (NOT LibEvent_FIND_QUIETLY)
+    message(STATUS "Found libevent: ${LIBEVENT_LIB}")
+  endif ()
+else ()
+  if (LibEvent_FIND_REQUIRED)
+    message(FATAL_ERROR "Could NOT find libevent.")
+  endif ()
+  message(STATUS "libevent NOT found.")
+endif ()
+
+mark_as_advanced(
+    LIBEVENT_LIB
+    LIBEVENT_INCLUDE_DIR
+  )

build/fbcode_builder/CMake/FindPCRE.cmake

+include(FindPackageHandleStandardArgs)
+find_path(PCRE_INCLUDE_DIR NAMES pcre.h)
+find_library(PCRE_LIBRARY NAMES pcre)
+find_package_handle_standard_args(
+  PCRE
+  DEFAULT_MSG
+  PCRE_LIBRARY
+  PCRE_INCLUDE_DIR
+)
+mark_as_advanced(PCRE_INCLUDE_DIR PCRE_LIBRARY)

build/fbcode_builder/CMake/ThriftCppLibrary.cmake

+# NOTE: If you change this file, fbcode/fboss/github/ThriftCppLibrary.cmake also
+# needs to be changed.  TODO: this should be handled via shipit.
+function(add_thrift_cpp2_library LIB_NAME THRIFT_FILE)
+  # Parse the arguments
+  set(SERVICES)
+  set(DEPENDS)
+  set(GEN_ARGS)
+  set(mode "UNSET")
+  foreach(arg IN LISTS ARGN)
+    if("${arg}" STREQUAL "SERVICES")
+      set(mode "SERVICES")
+    elseif("${arg}" STREQUAL "DEPENDS")
+      set(mode "DEPENDS")
+    elseif("${arg}" STREQUAL "OPTIONS")
+      set(mode "OPTIONS")
+    else()
+      if("${mode}" STREQUAL "SERVICES")
+        list(APPEND SERVICES "${arg}")
+      elseif("${mode}" STREQUAL "DEPENDS")
+        list(APPEND DEPENDS "${arg}")
+      elseif("${mode}" STREQUAL "OPTIONS")
+        list(APPEND GEN_ARGS "${arg}")
+      else()
+        message(
+          FATAL_ERROR
+          "expected SERVICES, DEPENDS, or OPTIONS argument, found ${arg}"
+        )
+      endif()
+    endif()
+  endforeach()
+
+  get_filename_component(base ${THRIFT_FILE} NAME_WE)
+  get_filename_component(
+    output_dir
+    ${CMAKE_CURRENT_BINARY_DIR}/${THRIFT_FILE}
+    DIRECTORY
+  )
+
+  list(APPEND GEN_ARGS "include_prefix=${output_dir}")
+  # CMake 3.12 is finally getting a list(JOIN) function, but until then
+  # treating the list as a string and replacing the semicolons is good enough.
+  string(REPLACE ";" "," GEN_ARG_STR "${GEN_ARGS}")
+
+  # Compute the list of generated files
+  list(APPEND generated_headers
+    ${output_dir}/gen-cpp2/${base}_constants.h
+    ${output_dir}/gen-cpp2/${base}_constants.cpp
+    ${output_dir}/gen-cpp2/${base}_types.h
+    ${output_dir}/gen-cpp2/${base}_types.tcc
+    ${output_dir}/gen-cpp2/${base}_types_custom_protocol.h
+  )
+  list(APPEND generated_sources
+    ${output_dir}/gen-cpp2/${base}_data.h
+    ${output_dir}/gen-cpp2/${base}_data.cpp
+    ${output_dir}/gen-cpp2/${base}_types.cpp
+  )
+  foreach(service IN LISTS SERVICES)
+    list(APPEND generated_headers
+      ${output_dir}/gen-cpp2/${service}.h
+      ${output_dir}/gen-cpp2/${service}.tcc
+      ${output_dir}/gen-cpp2/${service}AsyncClient.h
+      ${output_dir}/gen-cpp2/${service}_custom_protocol.h
+    )
+    list(APPEND generated_sources
+      ${output_dir}/gen-cpp2/${service}.cpp
+      ${output_dir}/gen-cpp2/${service}AsyncClient.cpp
+      ${output_dir}/gen-cpp2/${service}_processmap_binary.cpp
+      ${output_dir}/gen-cpp2/${service}_processmap_compact.cpp
+    )
+  endforeach()
+
+  # Emit the rule to run the thrift compiler
+  add_custom_command(
+    OUTPUT
+      ${generated_headers}
+      ${generated_sources}
+    COMMAND
+      ${CMAKE_COMMAND} -E make_directory ${output_dir}
+    COMMAND
+      ${FBTHRIFT_COMPILER}
+      --strict
+      --templates ${FBTHRIFT_TEMPLATES_DIR}
+      --gen "mstch_cpp2:${GEN_ARG_STR}"
+      -I ${CMAKE_SOURCE_DIR}
+      -o ${output_dir}
+      ${CMAKE_CURRENT_SOURCE_DIR}/${THRIFT_FILE}
+    WORKING_DIRECTORY
+      ${CMAKE_BINARY_DIR}
+    MAIN_DEPENDENCY
+      ${THRIFT_FILE}
+    DEPENDS
+      ${DEPENDS}
+  )
+
+  # Now emit the library rule to compile the sources
+  add_library(${LIB_NAME} STATIC
+    ${generated_sources}
+  )
+  set_property(
+    TARGET ${LIB_NAME}
+    PROPERTY PUBLIC_HEADER
+      ${generated_headers}
+  )
+  target_include_directories(
+    ${LIB_NAME}
+    PUBLIC
+      ${CMAKE_SOURCE_DIR}
+      ${CMAKE_BINARY_DIR}
+  )
+  target_link_libraries(
+    ${LIB_NAME}
+    PUBLIC
+      ${DEPENDS}
+      FBThrift::thriftcpp2
+  )
+endfunction()